Образовательный форум по автоматизации и взаимодействии с федеральными системами
Добро пожаловать, Гость! Чтобы использовать все возможности Вход. Новые регистрации запрещены.

Уведомление

Icon
Error

Опции
К последнему сообщению К первому непрочитанному
admin  
#1 Оставлено : 17 августа 2018 г. 8:17:13(UTC)
admin

Статус: Администрация
Сообщений: 1,474

Сказал(а) «Спасибо»: 2 раз
Поблагодарили: 10 раз в 6 постах
Вопрос:
1) При попытке загрузить присланный разработчиками внешний отчет (например, ГЗГУ или Мастер списков) в дополнительные отчеты появляется сообщение об ошибке:
Невозможно подключить дополнительный отчет из файла.
Возможно, он не подходит для этой версии программы.


Скриншот:
2018-08-17_9-04-20.png (210kb) загружен 0 раз(а).

2) Если пытаюсь открыть отчет через Файл – Открыть, то сообщение «Нарушение прав доступа».
Скриншот:

2018-08-17_9-07-01.png (199kb) загружен 0 раз(а).

Ответ:

1) Чтобы заработал первый вариант (загрузка в допотчеты), нужно доработать отчет, а именно добавить в модуль отчета следующий код:

Код:

Функция СведенияОВнешнейОбработке() Экспорт
	Версия = "15.08.2018";
	ПараметрыРегистрации = Новый Структура;
	ПараметрыРегистрации.Вставить("Вид", "ДополнительныйОтчет");
	ПараметрыРегистрации.Вставить("Назначение", "");
	ПараметрыРегистрации.Вставить("Наименование", "ГЗГУ от " + Версия);
	ПараметрыРегистрации.Вставить("Версия", Версия);
	ПараметрыРегистрации.Вставить("БезопасныйРежим", Ложь);
	ПараметрыРегистрации.Вставить("Информация", "ГЗГУ от " + Версия + " от разработчиков. ");
	
	ТаблицаКоманд = ПолучитьТаблицуКоманд();
	ДобавитьКоманду(ТаблицаКоманд, "ГЗГУ от " + Версия, "ГЗГУ_15082018", "ОткрытиеФормы", Истина);
	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
	 
	Возврат ПараметрыРегистрации; 
КонецФункции

Функция ПолучитьТаблицуКоманд()
 Команды = Новый ТаблицаЗначений;
 Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
 Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
 Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
 Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
 Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
 
 Возврат Команды;
КонецФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
 НоваяКоманда = ТаблицаКоманд.Добавить();
 НоваяКоманда.Представление = Представление;
 НоваяКоманда.Идентификатор = Идентификатор;
 НоваяКоманда.Использование = Использование;
 НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
 НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры


Скриншот:

2018-08-17_9-11-12.png (108kb) загружен 0 раз(а).

Скриншот:

2018-08-17_9-12-18.png (151kb) загружен 0 раз(а).

2) Чтобы заработало отрытые отчетов через Файл – Открыть, нужно пользователю, открывающему отчет предоставить право «Интерактивное открытие внешних отчетов и обработок»:

Скриншот:

2018-08-17_9-07-56.png (235kb) загружен 0 раз(а).

Следует с осторожностью предоставлять данное право, т.к. возможны определенные негативные последствия в случае открытия обработок из неизвестных источников. Рекомендуется использовать пункт 1 и загружать проверенные обработки и отчеты в справочник дополнительных обработок.

Отредактировано пользователем 28 августа 2018 г. 16:58:59(UTC)  | Причина: Не указана

Хотите присоединиться к дискуссии?! Войти в Ваш профиль форума. Новые регистрации запрещены.

Вы не можете создавать новые темы в этом форуме.
Вы не можете отвечать в этом форуме.
Вы не можете удалять Ваши сообщения в этом форуме.
Вы не можете редактировать Ваши сообщения в этом форуме.
Вы не можете создавать опросы в этом форуме.
Вы не можете голосовать в этом форуме.